Media Arts and Technology

Code: Select all

/*
Program written by Alexander Givens in 2012
Code adapted from http://www.neilwallis.com/java/water.html
*/

PImage img;

//Initiate a ripple object from the class below
Ripple ripple;

// Some holder vairbale for random ripples (like raindrops!)
int randX;
int randY;

//Prep the timer variables to space out drops
boolean timer = true;
int timeSnap;

//Image counter
int s = 1;
 
void setup() {
  img = loadImage(str(s) +".jpg");
  size(640, 426);
  ripple = new Ripple();
  frameRate(60);
  timeSnap = millis();
}
 
void draw() {
  loadPixels();
  img.loadPixels();
  for (int loc = 0; loc < width * height; loc++) {
    pixels[loc] = ripple.col[loc];
  }
  updatePixels();
  if (timer == true && millis() > timeSnap + 200) {
    randX = int(random(0, img.width));
    randY = int(random(0, img.height));
    for (int j = randY - ripple.riprad; j < randY + ripple.riprad; j++) {
      for (int k = randX - ripple.riprad; k < randX + ripple.riprad; k++) {
        if (j >= 0 && j < height && k>= 0 && k < width) {
          ripple.ripplemap[ripple.oldind + (j * width) + k] += 512;
        }
      }
    }
    timeSnap = millis();
  }
  ripple.newframe();
}

//Where the ripple magic happens!
class Ripple {
  int i, a, b;
  int oldind, newind, mapind;
  short ripplemap[]; // the height map
  int col[]; // the actual pixels
  int riprad;
  int rwidth, rheight;
  int ttexture[];
  int ssize;
 
  Ripple() {
    // constructor
    riprad = 3;
    rwidth = width >> 1;
    rheight = height >> 1;
    ssize = width * (height + 2) * 3;
    ripplemap = new short[ssize];
    col = new int[width * height];
    ttexture = new int[width * height];
    oldind = width;
    newind = width * (height + 3);
  }
 
 
 
  void newframe() {
    // update the height map and the image
    i = oldind;
    oldind = newind;
    newind = i;
 
    i = 0;
    mapind = oldind;
    for (int y = 0; y < height; y++) {
      for (int x = 0; x < width; x++) {
        short data = (short)((ripplemap[mapind - width] + ripplemap[mapind + width] +
          ripplemap[mapind - 1] + ripplemap[mapind + 1]) >> 1);
        data -= ripplemap[newind + i];
        data -= data >> 5;
        if (x == 0 || y == 0){ // avoid the wraparound effect
          ripplemap[newind + i] = 0;
        } else{
          ripplemap[newind + i] = data;
        }
        // where data = 0 then still, where data > 0 then wave
        data = (short)(1024 - data);
 
        // offsets
        a = ((x - rwidth) * data / 1024) + rwidth;
        b = ((y - rheight) * data / 1024) + rheight;
 
        //bounds check
        if (a >= width) {
          a = width - 1;
        }
        if (a < 0) {
          a = 0;
        }
        if (b >= height) {
          b = height-1;
        }
        if (b < 0) {
          b=0;
        }
 
        col[i] = img.pixels[a + (b * width)];
        mapind++;
        i++;
      }
    }
  }
}
 
 
void mouseDragged() {
  //Click and drag to make even more ripples
  for (int j = mouseY - ripple.riprad; j < mouseY + ripple.riprad; j++) {
    for (int k = mouseX - ripple.riprad; k < mouseX + ripple.riprad; k++) {
      if (j >= 0 && j < height && k>= 0 && k < width) {
        ripple.ripplemap[ripple.oldind + (j * width) + k] += 512;
      }
    }
  }
}

void keyPressed() {
  //Use left and right arrow keys to maneuver the image library
  if (keyCode == 39) {
    s += 1;
    if (s > 3) {
      s = 3;
    }
  }
  if (keyCode == 37) {
    s -= 1;
    if (s < 1) {
      s = 1;
    }
  }
  img = loadImage(str(s) + ".jpg");
}